Visual FX for Image FX/VisualFX for Image FX 3.adf/Files/ARexx/03/13.rexx

OS/2 REXX Batch file | 1997-08-07 | 4.7 KB | 239 lines

/*
                          Visual FX Arexx Script
                           Written By J.L. White
                         (C)1997 Merlin's Software
*/

Options Results
address "IMAGEFX.1"
ScreenToFront
Undo Off
if exists("libs:flyer.library") then do
    TOASTERLIB="ToasterARexx.port"
    call remlib('ToasterARexx.port')
    call remlib('PROJECT_REXX_PORT')
    call addlib('PROJECT_REXX_PORT' , 0)
    call addlib(TOASTERLIB,0)
    end
call Settings()
call open TempFile,"VFXIFX:TempDrawer/"FXNum".txt",R
line = readln(TempFile)
PicAName = strip(line)
line = readln(TempFile)
Start = strip(line)
line = readln(TempFile)
End = strip(line)
line = readln(TempFile)
IAType = strip(line)
line = readln(TempFile)
CompTotal = strip(line)
do i = 1 to CompTotal
    line = readln(TempFile)
    PicName.i = strip(line)
    line = readln(TempFile)
    Start.i = strip(line)
    line = readln(TempFile)
    End.i = strip(line)
    line = readln(TempFile)
    IAType.i = strip(line)
    line = readln(TempFile)
    BlendNum.i = strip(line)
    line = readln(TempFile)
    InType.i = strip(line)
    line = readln(TempFile)
    OutType.i = strip(line)
    line = readln(TempFile)
    FadeIn.i = strip(line)
    line = readln(TempFile)
    FadeOut.i = strip(line)
    line = readln(TempFile)
    FeatherNum.i = strip(line)
    line = readln(TempFile)
    DrawType.i = strip(line)
    line = readln(TempFile)
    DrawAnswer.i = strip(line)
    end
call close TempFile

Frames = (End - Start)+1
j=0
k=0
TFrames = Frames
TNum = 3
if TFrames > 999 then TNum = 4
if TFrames > 9999 then TNum = 5
if Field = 1 then TFrames = Frames*2
do i = Start to End
    k = k+ 1
    call open TempFile,"RAM:VFXNums",W
    call writeln TempFile,right(k,5,'0')
    call writeln TempFile,right(Frames,5,'0')
    call close TempFile
    f=0
    Redraw Off
    j = j+ 1
    FieldSet = 0
    call DoIt()
    Redraw On
    call SaveIt()
        if Field = 1 then do
            Redraw Off
            j = j + 1
            FieldSet = 1
            call DoIt()
            Redraw On
            call SaveIt()
            end
    end
    Undo On
exit



LoadA:
    if (POS('FLY_1',SHOW('Ports')) = 0) then do
        Undo On
        exit
        end
    if IAType = 0 then do
        LoadBuffer PicAName Force i
        end
    if IAType = 1 then do
        LoadBuffer PicAName Force 1
        end
    if IAType = 2 then do
        LoadBuffer PicAName Force
        end
    if IAType = 3 then do
        LoadBuffer PicAName""right(i,TNum,'0') Force
        end
return


LoadAll:
    if (POS('FLY_1',SHOW('Ports')) = 0) then do
        Undo On
        exit
        end
    if IAType.all = 0 then do
        LoadBuffer PicName.all Force (k+Start.all)-1
        end
    if IAType.all = 1 then do
        LoadBuffer PicName.all Force 1
        end
    if IAType.all = 2 then do
        LoadBuffer PicName.all Force
        end
    if IAType.all = 3 then do
        LoadBuffer PicName.all""right((k+Start.all)-1,TNum,'0') Force
        end
return


SaveIt:
    if (POS('FLY_1',SHOW('Ports')) = 0) then do
        Undo On
        exit
        end
    if SaveType = 0 then do
        call Switcher(TOSW)
        call Switcher(MDV1)

        Render Go
        if Field = 1 then
                call RecordAdd(SaveName,1,6,Compression)
        else
                call RecordAdd(SaveName,2,6,Compression)
        if j = TFrames then
            call MakeIcon(SaveName,(Frames-10))
        end

    if SaveType = 1 then do
        if Field = 1 then do
            f= f + 1
            if f = 1 then
                SaveBufferAs ILBM "VFXIFX:TempDrawer/PicA"
            if f = 2 then do
                GetMain
                parse var result Name Width Height Blah
                Scale Width Height/2
                Swap
                LoadBuffer "VFXIFX:TempDrawer/PicA" Force
                Scale Width Height/2
                Hook Interlace
                SaveBufferAs ILBM SaveName""right(k,TNum,'0')
                f = 0
                end
            end
        else do
            SaveBufferAs ILBM SaveName""right(k,TNum,'0')
            end
        end

return



GetFilled:
    PathFile = "VFXIFX:TempDrawer/DrawNum."FXNum"."right(all,2,'0')
    call open TempFile,PathFile,R
    NewArea
    do until eof(TempFile)
        line = readln(TempFile)
        AddArea line
        end
    FilledFree
    call close TempFile
return

DoIt:
    if (POS('FLY_1',SHOW('Ports')) = 0) then do
        Undo On
        exit
        end

    DrawStyle Normal
    Blend 100
    call LoadA()
    DrawStyle RubThrough
    GetMain
    parse var result Name Width Height Blah
    if j = 1 then do
        do all = 1 to CompTotal
            aa.all = 0
            end
        end
    do all = 1 to CompTotal
        Swap
        call LoadAll()
        Swap
        FadeNum = BlendNum.all
        if FadeIn.all > 0 & j <= FadeIn.all then do
            FadeNum = trunc(((j-1) * BlendNum.all) / (FadeIn.all-1))
            if FadeNum > BlendNum.all then FadeNum = BlendNum.all
            end
        if FadeOut.all > 0 & j >= (TFrames-FadeOut.all) then do
            aa.all = aa.all +1
            FadeNum = trunc(BlendNum.all-((aa.all-1) * BlendNum.all) / (FadeOut.all-1))
            if FadeNum > BlendNum.all then FadeNum = BlendNum.all
            end
        Blend FadeNum

        EdgeMode Normal
        if FeatherNum.all > 0 then EdgeMode FeatherOut FeatherNum.all


        if DrawType.all = 0 then FilledBox DrawAnswer.all
        if DrawType.all = 1 then FilledOval DrawAnswer.all
        if DrawType.all = 2 then call GetFilled()
        if DrawType.all = 3 then call GetFilled()
        EdgeMode Normal
        end

    DrawStyle Normal
    Blend 100

return